! jnl file that uses Argo data to make different temperature maps
! requires input arguments for time range, depth range and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_psal_time_series time_start time_end depth_min depth_max lat_min lat_max lon_min lon_max depth_axis con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.

! depth values are entered in the range of 0 - 2000dbar
! time values are entered corresponding to monthly values starting with Jan, 2004 
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.
! if no values are entered, the default region is 50S to 25N and 130E to 250E with an average over the 
! entire depth and time region
cancel/all data
cancel/all var
cancel/all sym
set window/clear
go set_pixel_size 1024 768
set mem/size=200
define viewport/xlim=.0,.95/ylim=0,1 top

PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15

! load in first file
use RG_ArgoClim_Temp_2014.nc
let t1=ARGO_TEMPERATURE_MEAN[d=1]+ARGO_TEMPERATURE_ANOMALY[d=1]


! now set up grid for entire time range
define axis/x=20.5E:19.5E:1/unit=degree xlong
define axis/y=64.5S:79.5N:1/unit=degree ylat
define axis/t="16-Jan-2004":"16-Dec-2023":1/units=months tclim
let dyn_p=z[d=1,g=`t1, return=grid`]	

define grid/x=xlong/y=ylat/z=dyn_p/t=tclim RG_grid


! now load in second temp file
use RG_ArgoClim_Temp_2024.nc
let t2=ARGO_TEMPERATURE_MEAN[d=2]+ARGO_TEMPERATURE_ANOMALY[d=2]

! now try to put all data onto same grid
let t_b1 = t1[gt=RG_grid@asn]
let t_b2 = t2[gt=RG_grid@nrst]


! load in first salinity file
use RG_ArgoClim_Psal_2014.nc
let s1=ARGO_SALINITY_MEAN[d=3]+ARGO_SALINITY_ANOMALY[d=3]

! now load in second psal file
use RG_ArgoClim_Psal_2024.nc
let s2=ARGO_SALINITY_MEAN[d=4]+ARGO_SALINITY_ANOMALY[d=4]

! now try to put all data onto same grid
let s_b1 = s1[gt=RG_grid@asn]
let s_b2 = s2[gt=RG_grid@nrst]


! mask out the current data
let mskt1 = if t_b1 then 1 else 0 

! define new full time scale data
let dyn_t = if mskt1 eq 1 then t_b1 else t_b2
let dyn_s = if mskt1 eq 1 then s_b1 else s_b2
let dyn_p = z[d=1,g=`t1, return=grid`]

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$5%30%`
let lat_max=`$6%35%`
let lon_min=`$7%170%`
let lon_max=`$8%170%`
let depth_min=`$3%0%`
let depth_max=`$4%1000%`
let time_start=`$1%1%`
let time_end=`$2%36%`
let depth_axis=`$9%0%`
set mode interpolate

if `depth_axis` then

! you want meters instead of db as the depth axis unit

! first need to change to depth from pressure
let xo=sin(y[g=`t1, return=grid`]*3.1415926/180)
let xxo=xo*xo
let bot_line=9.780318*(1.0+(5.2788*10^-3+2.36*10^-5*xxo)*xxo) + 1.092*10^-6*dyn_p
let top_line=(((-1.82*10^-15*dyn_p+2.279*10^-10)*dyn_p-2.2512*10^-5)*dyn_p+9.72659)*dyn_p
let dep=top_line/bot_line
ppl ylab Depth (meters)
! then regrid onto original pressure grid spacing
let psal=zaxreplace(dyn_s,dep,z[gz=`t1, return=grid`])

elseif

let psal=dyn_s

endif 

! Ensuring longitudes are properly plotted
let boundb=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `boundb` then
let lon_max=`lon_max`+360
endif


! only lat is the same
let a=if (`lat_min`) eq (`lat_max`) and (`lon_min`) ne (`lon_max`) then 1 else 0
if `a` then
let psal_time= psal[x=`lon_min`:`lon_max`@ave,y=`lat_min`,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif
! only lon is the same
let b=if `lon_min` eq `lon_max` and `lat_min` ne `lat_max` then 1 else 0
if `b` then 
let psal_time= psal[x=`lon_min`,y=`lat_min`:`lat_max`@ave,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`]
endif
! lat and lon are the same
let c=if `lon_min` eq `lon_max` and `lat_min` eq `lat_max` then 1 else 0
if `c` then
let psal_time= psal[x=`lon_min`,y=`lat_min`,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif
! both are different
let d=if `lon_min` ne `lon_max` and `lat_min` ne `lat_max` then 1 else 0
if `d` then
let psal_time= psal[x=`lon_min`:`lon_max`@ave,y=`lat_min`:`lat_max`@ave,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif

let con_lev= $10&"()"|*>"*"&

fill/nolab/pal=cofi_sal/z=`depth_max`:`depth_min`/set_up/lev="`con_lev`" psal_time
if `depth_axis` then 
ppl ylab Depth (meters)
elseif 
ppl ylab Pressure (dbar)
endif
ppl labset 0.2 0.2 0.2 0.2
ppl axlsze,0.15,0.15
ppl shakey 1,1,.08,0,5,9,,,, 
ppl fill
contour/set/over/nolab/color=black/z=`depth_max`:`depth_min`/lev="`con_lev`" psal_time
ppl conset,0.12
ppl conpre,0
ppl labset 0.2 0.2 0.2 0.2
ppl axlsze,0.15,0.15
ppl contour/over
ppl origin ,($orig_yorg)	!restore y origin

say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_psal_time_series time_start time_end depth_min depth_max lat_min lat_max lon_min lon_max con_lev