! jnl file that uses Argo data to make potential density time series anomaly plots from the monthly mean.
! This file requires input arguments for the time range, dynamic height levels and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_podens_time_series_monthly_anom time_start time_end depth_min depth_max lat_min lat_max lon_min lon_max depth_axis con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.
! depth values are entered in the range of 0 to 2000dbar
! time values are entered corresponding to monthly values starting with Jan, 2004 
! month values are entered in the range of 1-12 corresponding to the monthly anomaly you would like to look 
! ranging from Jan-Dec.  
! NOTE:  These plots only make sense if time and month values correspond.  In other words, if you want to look 
! at a January monthly anomaly, you choose '1' for month and then choose '1' for Jan. 2004, '13' for Jan. 2005,
! '25' for Jan. 2006, or '37' for Jan. 2007.  No other choices make sense.
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.
! if no values are entered, the default region is 50S to 25N and 130E to 250E with an average over the 
! time region and 0 to 1000dbar

cancel/all data
cancel/all var
cancel/all sym
set mem/size=200
set window/clear
go set_pixel_size 1024 768

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$5%-50%`
let lat_max=`$6%-50%`
let lon_min=`$7%140%`
let lon_max=`$8%150%`
let depth_min=`$3%0%`
let depth_max=`$4%1000%`
let time_start=`$1%1%`
let time_end=`$2%36%`
let depth_axis=`$9%0%`
set mode interpolate
set region/z=`depth_min`:`depth_max`/y=`lat_min`:`lat_max`/x=`lon_min`:`lon_max`
define viewport/xlim=.0,.95/ylim=0,1 top
PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15


! load in first file
use RG_ArgoClim_Temp_2014.nc
let t1=ARGO_TEMPERATURE_MEAN[d=1]+ARGO_TEMPERATURE_ANOMALY[d=1]


! now set up grid for entire time range
define axis/x=20.5E:19.5E:1/unit=degree xlong
define axis/y=64.5S:79.5N:1/unit=degree ylat
define axis/t="16-Jan-2004":"16-Dec-2023":1/units=months tclim
let dyn_p=z[d=1,g=`t1, return=grid`]	

define grid/x=xlong/y=ylat/z=dyn_p/t=tclim RG_grid


! now load in second temp file
use RG_ArgoClim_Temp_2024.nc
let t2=ARGO_TEMPERATURE_MEAN[d=2]+ARGO_TEMPERATURE_ANOMALY[d=2]

! now try to put all data onto same grid
let t_b1 = t1[gt=RG_grid@asn]
let t_b2 = t2[gt=RG_grid@nrst]


! load in first salinity file
use RG_ArgoClim_Psal_2014.nc
let s1=ARGO_SALINITY_MEAN[d=3]+ARGO_SALINITY_ANOMALY[d=3]

! now load in second psal file
use RG_ArgoClim_Psal_2024.nc
let s2=ARGO_SALINITY_MEAN[d=4]+ARGO_SALINITY_ANOMALY[d=4]

! now try to put all data onto same grid
let s_b1 = s1[gt=RG_grid@asn]
let s_b2 = s2[gt=RG_grid@nrst]


! mask out the current data
let mskt1 = if t_b1 then 1 else 0 

! define new full time scale data
let dyn_t = if mskt1 eq 1 then t_b1 else t_b2
let dyn_s = if mskt1 eq 1 then s_b1 else s_b2
let dyn_pres=z[d=1,g=`t1, return=grid`]


if `depth_axis` then

! you want meters instead of db as the depth axis unit

! first need to change to depth from pressure for temperature
let xo=sin(y[g=`t1, return=grid`]*3.1415926/180)
let xxo=xo*xo
let bot_line=9.780318*(1.0+(5.2788*10^-3+2.36*10^-5*xxo)*xxo) + 1.092*10^-6*dyn_pres
let top_line=(((-1.82*10^-15*dyn_pres+2.279*10^-10)*dyn_pres-2.2512*10^-5)*dyn_pres+9.72659)*dyn_pres
let dep=top_line/bot_line
! then regrid onto original pressure grid spacing
let temp=zaxreplace(dyn_t,dep,z[gz=`t1, return=grid`])

! second need to change to depth from pressure for salinity
let xos=sin(y[g=`t1, return=grid`]*3.1415926/180)
let xxos=xos*xos
let bot_line=9.780318*(1.0+(5.2788*10^-3+2.36*10^-5*xxos)*xxos) + 1.092*10^-6*dyn_pres
let top_line=(((-1.82*10^-15*dyn_pres+2.279*10^-10)*dyn_pres-2.2512*10^-5)*dyn_pres+9.72659)*dyn_pres
let dep=top_line/bot_line
! then regrid onto original pressure grid spacing
let psal=zaxreplace(dyn_s,dep,z[gz=`t1, return=grid`])

! now set pressure for density calculation

let dyn_p=dyn_pres

elseif

! you want db instead of m as the depth axis unit

let psal=dyn_s
let temp=dyn_t
let dyn_p=dyn_pres

endif


! calculate dynamic height

let dens=rho_un(psal,temp,dyn_p)
let potemp=THETA_FO(psal,temp,dyn_p,0)
let podens=rho_un(psal,potemp,0.)-1000


use climatological_axes.cdf
let clim_podens=podens[gt=month_irreg@mod]
let podens_anom=podens-clim_podens

! Ensuring longitudes are properly plotted
let boundb=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `boundb` then
let lon_max=`lon_max`+360
endif 


! begin mapping process
! potential density can only be plotted if the depths are different. 
! only lat is the same
let a=if (`lat_min`) eq (`lat_max`) and (`lon_min`) ne (`lon_max`) then 1 else 0
if `a` then 
let podens_time_anom= podens_anom[x=`lon_min`:`lon_max`@ave,y=`lat_min`,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif
! only lon is the same
let b=if `lon_min` eq `lon_max` and `lat_min` ne `lat_max` then 1 else 0
if `b` then 
let podens_time_anom= podens_anom[x=`lon_min`,y=`lat_min`:`lat_max`@ave,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`]
endif
! lat and lon are the same
let c=if `lon_min` eq `lon_max` and `lat_min` eq `lat_max` then 1 else 0
if `c` then
let podens_time_anom= podens_anom[x=`lon_min`,y=`lat_min`,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif
! both are different
let d=if `lon_min` ne `lon_max` and `lat_min` ne `lat_max` then 1 else 0
if `d` then
let podens_time_anom= podens_anom[x=`lon_min`:`lon_max`@ave,y=`lat_min`:`lat_max`@ave,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif

let anom_max=podens_time_anom[l=@max,z=@max]
let anom_min=podens_time_anom[l=@min,z=@min]
let abs_max=ABS(`anom_max`)
let abs_min=ABS(`anom_min`)
! case where anom_max is bigger than anom_min
let maxz=if `abs_max` gt `abs_min` and `abs_max` lt 1 then 1 else 0
if `maxz` then
let lev_max = (int(10*abs_max)+1)/10
let lev_min = (int(-10*abs_max)-1)/10
endif
let maxnz=if `abs_max` gt `abs_min` and `abs_max` gt 1 then 1 else 0
if `maxnz` then
let lev_max=int(anom_max)+1
let lev_min=int((-1*anom_max))-1
endif
let anom_diff=lev_max-lev_min
let anom_delta=anom_diff/8

! case where anom_min is bigger than anom_max
let minz=if `abs_min` gt `abs_max` and `abs_min` lt 1 then 1 else 0
if `minz` then
let lev_max = (int(10*abs_min)+1)/10
let lev_min = (int(10*anom_min)-1)/10
endif
let minnz=if `abs_min` gt `abs_max` and `abs_min` gt 1 then 1 else 0
if `minnz` then
let lev_max=int(abs_min)+1
let lev_min=int(anom_min)-1
endif
let anom_diff=lev_max-lev_min
let anom_delta=anom_diff/8

let con_lev= $10&"(`lev_min`,`lev_max`,`anom_delta`)"|*>"*"&

fill/nolab/pal=centered/lev="`con_lev`"/set_up podens_time_anom
if `depth_axis` then
ppl ylab Depth (meters)
elseif
ppl ylab Pressure (dbars)
endif
ppl labset 0.2 0.2 0.2 0.2
ppl axlsze,0.15,0.15
ppl shakey 1,1,.08,0,5,9,,,,  
ppl fill
contour/set/over/nolab/color=black/lev="`con_lev`" podens_time_anom
ppl conset,0.12
ppl conpre,0
ppl labset 0.2 0.2 0.2 0.2
ppl axlsze,0.15,0.15
ppl contour/over
ppl origin ,($orig_yorg)	!restore y origin




say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_podens_time_series_monthly_anom time_start time_end depth_min depth_max lat_min lat_max lon_min lon_max depth_axis con_lev