! jnl file that uses Argo data to make potential density plots
! requires input arguments for the time range, dynamic height levels and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_podens time_start time_end depth_top_level depth_bottom_level lat_min lat_max lon_min lon_max iland station depth_axis con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first variables as well as the lat/lon ranges.


! depth values are entered in the range of 0 to 2000dbar
! time values are entered in a range starting with Jan, 2004 
! iland  0=hig res, 1=low res go fland
! station 1=overlay stations, all other values disable
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.


cancel/all data
cancel/all var
cancel/all sym
set mem/size=200
set window/clear
go set_pixel_size 1024 768

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$5%-50%`
let lat_max=`$6%25%`
let lon_min=`$7%130%`
let lon_max=`$8%250%`
let depth_top=`$3%1000%`
let depth_bottom=`$4%1000%`
let time_start=`$1%36%`
let time_end=`$2%36%`
let iland=`$9%0%`
let station=`$10%0%`
let depth_axis=`$11%0%`
set mode interpolate
set region/z=`depth_top`:`depth_bottom`/y=`lat_min`:`lat_max`/x=`lon_min`:`lon_max`
define viewport/xlim=.0,.95/ylim=0,1 top
PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15


! load in first file
use RG_ArgoClim_Temp_2014.nc
let t1=ARGO_TEMPERATURE_MEAN[d=1]+ARGO_TEMPERATURE_ANOMALY[d=1]


! now set up grid for entire time range
define axis/x=20.5E:19.5E:1/unit=degree xlong
define axis/y=64.5S:79.5N:1/unit=degree ylat
define axis/t="16-Jan-2004":"16-Dec-2023":1/units=months tclim
let dyn_p=z[d=1,g=`t1, return=grid`]	

define grid/x=xlong/y=ylat/z=dyn_p/t=tclim RG_grid


! now load in second temp file
use RG_ArgoClim_Temp_2024.nc
let t2=ARGO_TEMPERATURE_MEAN[d=2]+ARGO_TEMPERATURE_ANOMALY[d=2]

! now try to put all data onto same grid
let t_b1 = t1[gt=RG_grid@asn]
let t_b2 = t2[gt=RG_grid@nrst]


! load in first salinity file
use RG_ArgoClim_Psal_2014.nc
let s1=ARGO_SALINITY_MEAN[d=3]+ARGO_SALINITY_ANOMALY[d=3]

! now load in second psal file
use RG_ArgoClim_Psal_2024.nc
let s2=ARGO_SALINITY_MEAN[d=4]+ARGO_SALINITY_ANOMALY[d=4]

! now try to put all data onto same grid
let s_b1 = s1[gt=RG_grid@asn]
let s_b2 = s2[gt=RG_grid@nrst]


! mask out the current data
let mskt1 = if t_b1 then 1 else 0 

! define new full time scale data
let temp = if mskt1 eq 1 then t_b1 else t_b2
let psal = if mskt1 eq 1 then s_b1 else s_b2


! checking on depth max.  If using meters, depth max is no longer 2000
let max_dep=if `depth_bottom` eq 2000 then 1 else 0

if `depth_axis` then

! you want meters instead of db as the depth axis unit

! first need to change to depth from pressure for temperature
let xo=sin(y[g=`t1, return=grid`]*3.1415926/180)
let xxo=xo*xo
let bot_line=9.780318*(1.0+(5.2788*10^-3+2.36*10^-5*xxo)*xxo) + 1.092*10^-6*dyn_pres
let top_line=(((-1.82*10^-15*dyn_pres+2.279*10^-10)*dyn_pres-2.2512*10^-5)*dyn_pres+9.72659)*dyn_pres
let dep=top_line/bot_line
! then regrid onto original pressure grid spacing
let dyn_t=zaxreplace(temp,dep,z[gz=`dyn_pres, return=grid`])

! second need to change to depth from pressure for salinity
let xos=sin(y[g=`s1, return=grid`]*3.1415926/180)
let xxos=xos*xos
let bot_line=9.780318*(1.0+(5.2788*10^-3+2.36*10^-5*xxos)*xxos) + 1.092*10^-6*dyn_pres
let top_line=(((-1.82*10^-15*dyn_pres+2.279*10^-10)*dyn_pres-2.2512*10^-5)*dyn_pres+9.72659)*dyn_pres
let dep=top_line/bot_line
! then regrid onto original pressure grid spacing
let dyn_s=zaxreplace(psal,dep,z[gz=`dyn_pres, return=grid`])

! now set pressure for density calculation

let dyn_p=dyn_pres

if `max_dep` then let depth_bottom=1900

else


! you want db instead of m as the depth axis unit

let dyn_t=temp
let dyn_s=psal
let dyn_p=z[d=1,g=`t1, return=grid`]

endif

! setting map scales properly
let beq=if (`lon_min`) eq (`lon_max`) then 1 else 0
if `beq` then
let lon_max=`lon_max`+360
endif
let blm=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `blm` then
let lon_max=`lon_max`+360
endif
define symbol xdeg `lon_max-lon_min`
define symbol ydeg `lat_max-lat_min`
define symbol alasp `($ydeg)/($xdeg)`
set win/asp=($alasp):axis

! setting depth region
set region/z=`depth_top`:`depth_bottom`

let dens=rho_un(dyn_s,dyn_t,dyn_p)
let potemp=THETA_FO(dyn_s,dyn_t,dyn_p,0)
let podens=rho_un(dyn_s,potemp,0.)-1000

! begin mapping process
! only plot averaged points if there is data down at the deepest layer
let mskd=if podens[x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`,z=`depth_bottom`] then 1
 
! depth is the same
let a=if `depth_top` eq `depth_bottom` and `time_start` ne `time_end` then 1 else 0
if `a` then
let podens_map=podens[x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`,z=`depth_top`,l=`time_start`:`time_end`@ave]
let con_lev= $12&"()"|*>"*"&
fill/nolab/pal=default/set/x=`lon_min`:`lon_max`/y=`lat_min`:`lat_max`/lev="`con_lev`" podens_map
ppl shakey 1,,.08,,5,,,,,,
ppl fill
! can add contours 
 con/set/over/nolab/lev="`con_lev`" podens_map
 ppl conset .08,,,,,,,5.7,1.,1
 ppl contour/overlay
endif

!time is the same
let b=if `time_start` eq `time_end` and `depth_top` ne `depth_bottom` then 1 else 0
if `b` then 
let podens_map=if mskd[l=`time_start`] eq 1 then podens[x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`,l=`time_start`,z=`depth_top`:`depth_bottom`@ave]
let con_lev= $12&"()"|*>"*"&
fill/nolab/pal=default/set/x=`lon_min`:`lon_max`/y=`lat_min`:`lat_max`/lev="`con_lev`" podens_map
ppl shakey 1,,.08,,5,,,,,,
ppl fill
! can add contours 
 con/set/over/nolab/lev="`con_lev`" podens_map
 ppl conset .08,,,,,,,5.7,1.,1
 ppl contour/overlay
endif

!both are same
let c= if `time_start` eq `time_end` and `depth_top` eq `depth_bottom` then 1 else 0
if `c` then 
let podens_map=if mskd[l=`time_start`] eq 1 then podens[x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`, l=`time_start`,z=`depth_top`]
let con_lev= $12&"()"|*>"*"&
fill/nolab/set/pal=default/lev="`con_lev`" podens_map
ppl shakey 1,,.08,,5,,,,,,
ppl fill
! can add contours over the dynamic height plot
 con/set/over/nolab/lev="`con_lev`" podens_map
 ppl conset .08,,,,,,,5.7,1.,1
 ppl contour/overlay
endif

!both are different
let d= if `time_start` ne `time_end` and `depth_top` ne `depth_bottom` then 1 else 0
if `d` then 
let podens_map=if mskd[l=`time_start`:`time_end`@ave] eq 1 then podens[x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`, l=`time_start`:`time_end`@ave,z=`depth_top`:`depth_bottom`@ave]
let con_lev= $12&"()"|*>"*"&
fill/nolab/set/pal=default/lev="`con_lev`" podens_map
ppl shakey 1,,.08,,5,,,,,,
ppl fill
! can add contours over the dynamic height plot
 con/set/over/nolab/lev="`con_lev`" podens_map
 ppl conset .08,,,,,,,5.7,1.,1
 ppl contour/overlay
endif

! now use etopo6 to add bathymetry
! check zonal range to see if using high or low land resoluion
let rcheck=`lon_max`-`lon_min`
if `rcheck gt 120` then
if `iland eq 0` then
use etopo12_grid.nc
shade/over/nokey/nolab/pal=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/lev=(0,10000,10000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shade/over/nokey/nolab/palette=lightgreyscale/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-1000,0,1000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shade/over/nokey/nolab/pal=grey/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/lev=(-200,0,200) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif
if `iland eq 1` then
use etopo12_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif
endif
if `rcheck le 120` then
if `iland eq 0` then
use etopo6_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
fill/over/nokey/nolab/palette=lightgreyscale/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-1000,0,1000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
fill/over/nokey/nolab/palette=grey/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-200,0,200) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
else
use etopo6_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif

endif
if `station eq 1` then
go fer_psal_station_loc_overlay
endif

say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_podens time_start time_end depth_top_level depth_bottom_level lat_min lat_max lon_min lon_max iland station depth_axis con_lev