! jnl file that uses Argo data to make different temperature maps
! requires input arguments for time range, depth range and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_temp_time_series time_start time_end depth_min depth_max lat_min lat_max lon_min lon_max con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.

! depth values are entered in the range of 0 - 2000dbar
! time values are entered corresponding to monthly values starting with Jan, 2004 
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.
! if no values are entered, the default region is 50S to 25N and 130E to 250E with an average over the 
! entire depth and time region
cancel/all data
cancel/all var
cancel/all sym
set window/clear
!go set_pixel_size 1024 768

! set the aspect ratio
SET WINDOW/ASPECT=.75
!
! set window size. Note that the default window has a size of .7
set window/size=`((1024*768)/(781*674))*.9`

set mem/size=80

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$5%(50)%`
let lat_max=`$6%(50)%`
let lon_min=`$7%(170)%`
let lon_max=`$8%(170)%`
let depth_min=`$3%0%`
let depth_max=`$4%500%`
let time_start=`$1%1%`
let time_end=`$2%48%`

set region/z=`depth_min`:`depth_max`/y=`lat_min`:`lat_max`/x=`lon_min`:`lon_max`
define viewport/xlim=.0,.95/ylim=0,1 top

PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15


use RG_ArgoClim_Full.nc
let temp=ARGO_TEMPERATURE_MEAN[d=1]+ARGO_TEMPERATURE_ANOMALY[d=1]
let psal=ARGO_SALINITY_MEAN[d=1]+ARGO_SALINITY_ANOMALY[d=1]

! Ensuring longitudes are properly plotted
let boundb=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `boundb` then
let lon_max=`lon_max`+360
endif 

! only lat is the same
let a=if (`lat_min`) eq (`lat_max`) and (`lon_min`) ne (`lon_max`) then 1 else 0
if `a` then 
let temp_time= temp[x=`lon_min`:`lon_max`@ave,y=`lat_min`,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif
! only lon is the same
let b=if (`lon_min`) eq (`lon_max`) and (`lat_min`) ne (`lat_max`) then 1 else 0
if `b` then 
let temp_time= temp[x=`lon_min`,y=`lat_min`:`lat_max`@ave,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`]
endif
! lat and lon are the same
let c=if (`lon_min`) eq (`lon_max`) and (`lat_min`) eq (`lat_max`) then 1 else 0
if `c` then
let temp_time= temp[x=`lon_min`,y=`lat_min`,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif
! both are different
let d=if (`lon_min`) ne (`lon_max`) and `lat_min` ne `lat_max` then 1 else 0
if `d` then
let temp_time= temp[x=`lon_min`:`lon_max`@ave,y=`lat_min`:`lat_max`@ave,z=`depth_min`:`depth_max`,l=`time_start`:`time_end`] 
endif

let con_lev= $9&"()"|*>"*"&

fill/nolab/pal=cofi_pot/z=`depth_max`:`depth_min`/set_up/lev="`con_lev`" temp_time
ppl ylab Pressure(dbar)
ppl labset 0.2 0.2 0.2 0.2
ppl axlsze,0.15,0.15
ppl shakey 1,1,.08,0,5,9,,,,  
ppl fill
contour/set/over/nolab/color=black/z=`depth_max`:`depth_min`/lev="`con_lev`"  temp_time
ppl conset,0.12
ppl conpre,0
ppl labset 0.2 0.2 0.2 0.2
ppl axlsze,0.15,0.15
ppl contour/over
ppl origin ,($orig_yorg)	!restore y origin



say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_temp_time_series time_start time_end depth_min depth_max lat_min lat_max lon_min lon_max con_lev