! jnl file that uses Argo data to make mixed layer depth maps
! requires input arguments for time range and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_mld time_start time_end lat_min lat_max lon_min lon_max iland station con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.

! time values are entered corresponding to monthly values starting with Jan, 2004 
! iland  0=hig res, 1=low res go fland
! station 1=overlay stations, all other values disable
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.
! if no values are entered, the default region is 50S to 25N and 130E to 250E with an average over the 
! entire depth and time region
cancel/all data
cancel/all var
cancel/all sym
cancel region
set window/clear
go set_pixel_size 1024 768
set mem/size=80

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$3%-62%`
let lat_max=`$4%0%`
let lon_min=`$5%140%`
let lon_max=`$6%290%`
let time_start=`$1%56%`
let time_end=`$2%56%`
let iland=`$7%1%`
let station=`$8%0%`
set mode interpolate


PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl pen 2,13
ppl labset .15,.15,.15


! setting map scales properly
let beq=if (`lon_min`) eq (`lon_max`) then 1 else 0
if `beq` then
let lon_max=`lon_max`+360
endif
let blm=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `blm` then
let lon_max=`lon_max`+360
endif
define symbol xdeg `lon_max-lon_min`
define symbol ydeg `lat_max-lat_min`
define symbol alasp `($ydeg)/($xdeg)`
set win/asp=($alasp):axis
define region/y=`lat_min`:`lat_max`/x=`lon_min`:`lon_max` mreg
set region mreg
define viewport/xlim=.0,.95/ylim=0,1 top

use RG_ArgoClim_Full.nc
use climatological_axes

let dyn_s = argo_salinity_mean[d=1] + argo_salinity_anomaly[d=1]
let dyn_t = argo_temperature_mean[d=1]+argo_temperature_anomaly[d=1]

define grid/like=dyn_t arg_grd
let dyn_p = z[d=1,g=arg_grd]
let dens = rho_un(dyn_s, dyn_t, dyn_p)
let potemp = theta_fo(dyn_s, dyn_t, dyn_p, 0.)
let podens = rho_un(dyn_s, potemp, 0.)-1000.
go dynamic_height


let delta_dens= podens-podens[z=5]
define axis/z=0:1:.01 axden
let presonsigma = zaxreplace(dyn_p,delta_dens,z[gz=axden])

let con_lev= $9&"()"|*>"*"&
fill/nolab/set/pal=default/lev="`con_lev`" presonsigma[z=.03,l=`time_start`:`time_end`@ave]
stat
ppl fill

con/over/nolab/set dyn_t[z=0,l=`time_start`:`time_end`@ave]
ppl contour/over

! now use etopo6 to add bathymetry
! check zonal range to see if using high or low land resoluion
let rcheck=`lon_max`-`lon_min`
if `rcheck gt 120` then
if `iland eq 0` then
use etopo12_grid.nc
shade/over/nokey/nolab/pal=black/lev=(0,10000,10000) btdata12
shade/over/nokey/nolab/palette=lightgreyscale/over/levels=(-1000,0,1000) btdata12
shade/over/nokey/nolab/pal=grey/over/lev=(-200,0,200) btdata12
endif
if `iland eq 1` then
use etopo12_grid.nc
fill/over/nokey/nolab/palette=black/levels=(0,10000,10000) btdata12
endif
endif
if `rcheck le 120` then
if `iland eq 0` then
use etopo6_grid.nc
fill/over/nokey/nolab/palette=black/levels=(0,10000,10000) btdata
fill/over/nokey/nolab/palette=lightgreyscale/over/levels=(-1000,0,1000) btdata
fill/over/nokey/nolab/palette=grey/over/levels=(-200,0,200) btdata
else
use etopo6_grid.nc
fill/over/nokey/nolab/palette=black/levels=(0,10000,10000) btdata
endif

endif
if `station eq 1` then
go fer_psal_station_loc_overlay
endif

say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_mld time_start time_end lat_min lat_max lon_min lon_max iland station con_lev