! jnl file that uses Argo data to make geostrophic velocity section plots
! requires input arguments for the time range, dynamic height levels and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_geo_vel_section_real_time section_direction ylo yhi depth_min depth_max xlo xhi con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.


! section direction can be "N" for N-S or "E" for E-W

! xlo corresponds to the lowest latitude limit  
! xhi corresponds to the highest latitude limit  
! ylo corresponds to the lowest longitude limit 
! yhi corresponds to the highest longitude limit

! depth values are entered in the range of 0 - 2000dbar with the default being 0 - 1000dbar
! time values are entered corresponding to monthly values starting with Jan, 2004 
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.


cancel/all data
cancel/all var
cancel/all sym
set mem/size=70
set window/clear
go set_pixel_size 1024 768

define viewport/xlim=.0,.95/ylim=0,1 top
PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15

use RG_ArgoClim_Real_Time.nc
let temp=argo_temperature_mean[d=1]+argo_temperature_anomaly[d=1]+argo_temperature_annual_anomaly[d=1]
let psal=ARGO_SALINITY_MEAN[d=1]+ARGO_SALINITY_ANOMALY[d=1]+argo_salinity_annual_anomaly[d=1]
let dyn_p=z[d=1,g=`temp, return=grid`]

let depth_min=`$4%0%`
let depth_max=`$5%500%`

! setting the default values
let xlo=`$6%165%`
let xhi=`$7%170%`
let ylo=`$2%-30%`
let yhi=`$3%30%`
set mode interpolate
! setting depth region
set region/z=`depth_min`:`depth_max`

! calculate dynamic height
let dyn_s=psal[d=1]
let dyn_t=temp[d=1]
let dyn_p=z[d=1,g=`temp, return=grid`]

let dens=rho_un(dyn_s,dyn_t,dyn_p)
let potemp=THETA_FO(dyn_s,dyn_t,dyn_p,0)
let podens=rho_un(dyn_s,potemp,0.)-1000

go dynamic_height

! begin mapping process
! don't want to plot geostrophic velocity within 5 degrees of equator 
let msk=if y[g=`temp,return=grid`] lt 5 and y[g=`temp,return=grid`] gt (-5) then 0 else 1


! geostrophic velocity can only be plotted if the depths are different. 
! depth is the same
let a=if `depth_min` eq `depth_max` then 1 else 0
if `a` then say "depth is the same - cannot graph velocity"

let c=if (`xlo`) ne (`xhi`) then 1 else 0
let d=if (`ylo`) ne (`yhi`) then 1 else 0
let boundb=if (`xlo`) gt (`xhi`) then 1 else 0

! must start with bathymetry in order to plot velocity over 


! now can start plotting velocity vectors over

let vel_u=if msk[d=1] eq 1 then geo_uz 
let vel_v=if msk[d=1] eq 1 then geo_vz
if ($1%TRUE|N>TRUE|E>FALSE|>TRUE%) then 	!checking whether it is a N-S or E-W section & assigning N-S as default
if `c` then

! plotting
let geo_vel=vel_u[y=`ylo`:`yhi`,x=`xlo`:`xhi`@ave,z=`depth_min`:`depth_max`]
let anom_max=geo_vel[y=@max,z=@max]
let anom_min=geo_vel[z=@min,y=@min]

else ! no averaging over x

! plotting

let geo_vel= vel_u[y=`ylo`:`yhi`,x=`xlo`,z=`depth_min`:`depth_max`]
let anom_max=geo_vel[y=@max,z=@max]
let anom_min=geo_vel[z=@min,y=@min]

endif	! c loop

else ! E-W section

! Ensuring longitudes are properly plotted
if `boundb` then
let xhi=`xhi`+360
endif 

if `d` then 

! plotting
let geo_vel=vel_v[y=`ylo`:`yhi`@ave,x=`xlo`:`xhi`,z=`depth_min`:`depth_max`]
let anom_max=geo_vel[x=@max,z=@max]
let anom_min=geo_vel[z=@min,x=@min]

else ! no averaging over y

! plotting
let geo_vel= vel_v[x=`xlo`:`xhi`,y=`ylo`,z=`depth_min`:`depth_max`]
let anom_max=geo_vel[x=@max,z=@max]
let anom_min=geo_vel[z=@min,x=@min]

endif	! d loop

endif !n-s


! creating an equal, centered key
let abs_max=ABS(`anom_max`)
let abs_min=ABS(`anom_min`)
! case where anom_max is bigger than anom_min
let maxz=if `abs_max` gt `abs_min` and `abs_max` lt 1 then 1 else 0
if `maxz` then
let lev_max = (int(10*abs_max)+1)/10
let lev_min = (int(-10*abs_max)-1)/10
endif
let maxnz=if `abs_max` gt `abs_min` and `abs_max` gt 1 then 1 else 0
if `maxnz` then
let lev_max=int(anom_max)+1
let lev_min=int((-1*anom_max))-1
endif
let anom_diff=lev_max-lev_min
let anom_delta=anom_diff/8

! case where anom_min is bigger than anom_max
let minz=if `abs_min` gt `abs_max` and `abs_min` lt 1 then 1 else 0
if `minz` then
let lev_max = (int(10*abs_min)+1)/10
let lev_min = (int(10*anom_min)-1)/10
endif
let minnz=if `abs_min` gt `abs_max` and `abs_min` gt 1 then 1 else 0
if `minnz` then
let lev_max=int(abs_min)+1
let lev_min=int(anom_min)-1
endif
let anom_diff=lev_max-lev_min
let anom_delta=anom_diff/8

let con_lev= $8&"(`lev_min`,`lev_max`,`anom_delta`)"|*>"*"&

! plotting
fill/set/nolab/pal=centered/lev="`con_lev`"  geo_vel
ppl shakey 1,,.08,,5,,,,,,
ppl ylab Pressure (dbar)
ppl fill
 
! adding contours
 con/set_up/over/nolab/lev="`con_lev`" geo_vel 
 ppl conset .11,,,,,,,5.7,1.,1
 ppl contour/overlay


! adding in etopo6 to give bathymetry
use etopo6_grid.nc

if ($1%TRUE|N>TRUE|E>FALSE|>TRUE%) then 	! N-S section

! making a mask to put in bathymetry only where there is land
if `c` then
let mskb if btdata*(-1) lt dyn_p then 1
shad/nolab/nokey/over/pal=black mskb[x=`xlo`,y=`ylo`:`yhi`,z=`depth_min`:`depth_max`]
repeat/x=`xlo`:`xhi` shad/nolab/over/nokey/pal=black mskb[y=`ylo`:`yhi`,z=`depth_min`:`depth_max`]

else
let mskb if btdata*(-1) lt dyn_p then 1
shad/nolab/nokey/over/pal=black mskb[x=`xlo`,y=`ylo`:`yhi`,z=`depth_min`:`depth_max`]
endif

else	! E-W section

! making a mask to put in bathymetry only where there is land
if `d` then
let mskb if btdata*(-1) lt dyn_p then 1
shad/nolab/nokey/over/pal=black mskb[x=`xlo`:`xhi`,y=`ylo`,z=`depth_min`:`depth_max`]
repeat/y=`ylo`:`yhi` shad/nolab/nokey/over/pal=black mskb[x=`xlo`:`xhi`,z=`depth_min`:`depth_max`]

else
let mskb if btdata*(-1) lt dyn_p then 1
shad/nolab/nokey/over/pal=black mskb[y=`ylo`,x=`xlo`:`xhi`,z=`depth_min`:`depth_max`]
endif
endif 	! ns loop

say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_geo_vel_section_real_time section_direction ylo yhi depth_min depth_max xlo xhi con_lev