! jnl file that uses Argo data to make different average dynamic height maps
! requires input arguments for month, depth range and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_dyn_ht_avg_map month depth_min depth_max lat_min lat_max lon_min lon_max iland station geo_vel con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.

! depth values are entered in the range of 0 - 2000dbar
! time values are entered corresponding to monthly values starting with Jan, 2004 
! iland  0=hig res, 1=low res go fland
! station 1=overlay stations, all other values disable
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.

! if no values are entered, the default region is 50S to 25N and 130E to 250E with an average over the 
! entire depth and Jan 2007
cancel/all data
cancel/all var
cancel/all sym
set window/clear
go set_pixel_size 1024 768
set mem/size=80

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$4%-50%`
let lat_max=`$5%25%`
let lon_min=`$6%130%`
let lon_max=`$7%250%`
let depth_min=`$2%0%`
let depth_max=`$3%100%`
let month=`$1%24%`
let iland=`$8%1%`
let station=`$9%0%`
let geo_vel=`$10%1%`
set mode interpolate

set region/z=`depth_min`:`depth_max`/y=`lat_min`:`lat_max`/x=`lon_min`:`lon_max`
define viewport/xlim=.0,.95/ylim=0,1 top

PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15

use RG_ArgoClim_Full.nc
let temp=ARGO_TEMPERATURE_MEAN[d=1]+ARGO_TEMPERATURE_ANOMALY[d=1]
let psal=ARGO_SALINITY_MEAN[d=1]+ARGO_SALINITY_ANOMALY[d=1]
use "c:\marineatlas\ferret\TMAP\fer_dsets\data\climatological_axes.cdf"


! setting map scales properly
let beq=if (`lon_min`) eq (`lon_max`) then 1 else 0
if `beq` then
let lon_max=`lon_max`+360
endif
let blm=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `blm` then
let lon_max=`lon_max`+360
endif
define symbol xdeg `lon_max-lon_min`
define symbol ydeg `lat_max-lat_min`
define symbol alasp `($ydeg)/($xdeg)`
set win/asp=($alasp):axis

! calculate dynamic height
let dyn_s=psal[d=1]
let dyn_t=temp[d=1]
let dyn_p=z[d=1,g=`temp, return=grid`]

go dynamic_height

let dens=rho_un(dyn_s,dyn_t,dyn_p)
let potemp=THETA_FO(dyn_s,dyn_t,dyn_p,0)
let podens=rho_un(dyn_s,potemp,0.)-1000
let clim_dyn_ht=dyn_ht[gt=month_irreg@mod]

! begin mapping process

! only map an average if the two depths/times are different.  otherwise, map at that depth/time only

! depth is the same
let a=if `depth_max` eq `depth_min` then 1 else 0
if `a` then say "depth is the same - cannot graph the potential density"


!both are different
let d= if `depth_max` ne `depth_min` then 1 else 0
if `d` then 
let dyn_ht_map= clim_dyn_ht[x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`,l=`month`,z=`depth_min`:`depth_max`] 
endif

let con_lev= $11&"()"|*>"*"&
fill/nolab/pal=default/set/lev="`con_lev`" dyn_ht_map
ppl shakey 1,1,.08,0,5,9,,,,
ppl fill
! adding contours
 con/set_up/nolab/over/lev="`con_lev`" dyn_ht_map
 ppl conset .11,,,,,,,5.7,1.,1
 ppl contour/overlay

! now use etopo6 to add bathymetry
! check zonal range to see if using high or low land resoluion
let rcheck=`lon_max`-`lon_min`
if `rcheck gt 120` then
if `iland eq 0` then
use etopo12_grid.nc
shade/over/nokey/nolab/pal=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/lev=(0,10000,10000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shade/over/nokey/nolab/palette=lightgreyscale/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-1000,0,1000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shade/over/nokey/nolab/pal=grey/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/lev=(-200,0,200) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif
if `iland eq 1` then
use etopo12_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif
endif
if `rcheck le 120` then
if `iland eq 0` then
use etopo6_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
fill/over/nokey/nolab/palette=lightgreyscale/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-1000,0,1000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
fill/over/nokey/nolab/palette=grey/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-200,0,200) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
else
use etopo6_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif

endif
if `station eq 1` then
go fer_psal_avg_station_loc_overlay
endif

if `geo_vel eq 1` then
go fer_geo_vel_avg_map_overlay 
endif


say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_dyn_ht_avg_map month depth_min depth_max lat_min lat_max lon_min lon_max iland station geo_vel con_lev