! jnl file to make sea surface temperature (SST) maps
! requires input arguments for lat/lon range and time range.  If none are entered, default values will be used.

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_sst_hovmoller time_start time_end lat_min lat_max lon_min lon_max con_lev


! latitude values are entered in the range of -90 - 90.
! longitude values are entered in the range of 0 - 360
! time values are entered in a range starting with Jan, 2004 
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.


set mem/size=80
set window/clear
go set_pixel_size 1024 768

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$3%-2%`
let lat_max=`$4%2%`
let lon_min=`$5%130%`
let lon_max=`$6%250%`
let time_start=`$1%1%`
let time_end=`$2%53%`

! set the aspect ratio
SET WINDOW/ASPECT=.75
define viewport/xlim=.0,.95/ylim=0,1 top
cancel/all data
PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15

use reynolds_sst_grid.nc

set mode interpolate

! begin mapping process

! Ensuring longitudes are properly plotted
let boundb=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `boundb` then
let lon_max=`lon_max`+360
endif

! only map an average if the times are different.  otherwise, map at that time only

! lat is the same
let a=if (`lat_min`) eq (`lat_max`) then 1 else 0
! lat is different
let b= if (`lat_min`) ne (`lat_max`) then 1 else 0

if `a` then 
let sst_time=sst[d=1,x=`lon_min`:`lon_max`,y=`lat_min`,l=`time_start`:`time_end`]
endif
if `b` then
let sst_time=sst[d=1,x=`lon_min`:`lon_max`,y=`lat_min`:`lat_max`@ave,l=`time_start`:`time_end`] 
endif


let con_lev= $7&"()"|*>"*"&

! plotting
fill/set/nolab/pal=cofi_pot/lev="`con_lev`"  sst_time
ppl shakey 1,,.08,,5,,,,,,
ppl fill
 
! adding contours
 con/set_up/over/nolab/lev="`con_lev`" sst_time 
 ppl conset .11,,,,,,,5.7,1.,1
 ppl contour/overlay


say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_sst_hovmoller time_start time_end lat_min lat_max lon_min lon_max con_lev