! jnl file that uses Argo data to make different salinity maps
! requires input arguments for time range, depth range and lat/lon range

! to run the program in ferret, you will need to type the following line with the various values filled in:

!  go fer_psal_map_dens time_start time_end dens_min dens_max lat_min lat_max lon_min lon_max iland station depth_axis con_lev

! If you choose not to give values for the various variables, default ones will be substituted for you.
! If you only want to choose some values, you can, but you cannot skip any values.  This means you can 
! fill in the first 2 and no others, or if you want to specify the lat/lon ranges, you must fill in values
! for the first 4 variables as well as the lat/lon ranges.

! density values are entered in the range of 21 - 28 kg/m^3
! time values are entered corresponding to monthly values starting with Jan, 2004 
! iland  0=hig res, 1=low res go fland
! station 1=overlay stations, all other values disable
! con_lev sets the contour and fill levels of the plot.  This is done in the following format:  (lo,hi,delta).  
! More than one can be chosen:  (lo,mid,delta1),(mid,hi,delta2).  See the Ferret Users Manual for more information.
! if no values are entered, the default region is 50S to 25N and 130E to 250E with an average over the 
! entire depth and time region
cancel/all data
cancel/all var
cancel/all sym
cancel/all region
set window/clear
go set_pixel_size 1024 768
set mem/size=100

! assigning variables to arguments passed in the go command as well as default values
let lat_min=`$5%-50%`
let lat_max=`$6%20%`
let lon_min=`$7%120%`
let lon_max=`$8%300%`
let dens_min=`$3%23%`
let dens_max=`$4%23%`
let time_start=`$1%16%`
let time_end=`$2%16%`
let iland=`$9%1%`
let station=`$10%1%`
let depth_axis=`$11%0%`
set mode interpolate

PPL DFLTFNT DR
ppl conpre @P1@DR
ppl axlsze 0.15,.15
ppl axset 1,1,1,1
ppl pen 0,7
ppl pen 1,7
ppl labset .15,.15,.15


use RG_ArgoClim_Full.nc
let dyn_t=ARGO_TEMPERATURE_MEAN[d=1]+ARGO_TEMPERATURE_ANOMALY[d=1]
let dyn_s=ARGO_SALINITY_MEAN[d=1]+ARGO_SALINITY_ANOMALY[d=1]
let dyn_p=z[d=1,g=`dyn_t, return=grid`]


! setting map scales properly
let beq=if (`lon_min`) eq (`lon_max`) then 1 else 0
if `beq` then
let lon_max=`lon_max`+360
endif
let blm=if (`lon_min`) gt (`lon_max`) then 1 else 0
if `blm` then
let lon_max=`lon_max`+360
endif
define symbol xdeg `lon_max-lon_min`
define symbol ydeg `lat_max-lat_min`
define symbol alasp `($ydeg)/($xdeg)`
set win/asp=($alasp):axis
define region/y=`lat_min`:`lat_max`/x=`lon_min`:`lon_max` mreg
set region mreg 
define viewport/xlim=.0,.95/ylim=0,1 top



! you want density surfaces instead of db as the depth axis unit

! first need to calculate density sigma and density axis axden
let dens=rho_un(dyn_s,dyn_t,dyn_p)
let potemp=THETA_FO(dyn_s,dyn_t,dyn_p,0)
let podens=rho_un(dyn_s,potemp,0.)-1000
define axis/z=21:28:.05 axden

! then regrid onto density grid spacing
let psal=zaxreplace(dyn_s,podens,z[gz=axden])




! begin mapping process
! only map an average if the two depths/times are different.  otherwise, map at that depth/time only
! only plot averaged points if there is data down at the deepest layer


! depth is the same
let a=if `dens_max` eq `dens_min` then 1 else 0

if `a` then 
let psal_map=psal[z=`dens_min`,l=`time_start`:`time_end`@ave]
endif


! depth is different
let b=if `dens_max` ne `dens_min` then 1 else 0
if `b` then 

let psal_map=psal[z=`dens_min`:`dens_max`@ave,l=`time_start`:`time_end`@ave] 
endif


let con_lev= $12&"()"|*>"*"&
fill/nolab/set/palette=cofi_sal/lev="`con_lev`" psal_map
ppl shakey 1,,.08,,5,,,,,,
ppl fill
! adding contours
 con/set_up/nolab/over/lev="`con_lev`" psal_map
 ppl conset .11,,,,,,,5.7,1.,1 ! was .11
 ppl contour/overlay


! now use etopo6 to add bathymetry
! check zonal range to see if using high or low land resoluion
let rcheck=`lon_max`-`lon_min`
if `rcheck gt 120` then
if `iland eq 0` then
use etopo12_grid.nc
shade/over/nokey/nolab/pal=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/lev=(0,10000,10000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shade/over/nokey/nolab/palette=lightgreyscale/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-1000,0,1000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shade/over/nokey/nolab/pal=grey/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/lev=(-200,0,200) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif
if `iland eq 1` then
use etopo12_grid.nc
fill/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata12[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif
endif
if `rcheck le 120` then
if `iland eq 0` then
use etopo6_grid.nc
shad/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shad/over/nokey/nolab/palette=lightgreyscale/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-1000,0,1000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
shad/over/nokey/nolab/palette=grey/over/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(-200,0,200) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
else
use etopo6_grid.nc
shad/over/nokey/nolab/palette=black/hlim=`lon_min`:`lon_max`/vlim=`lat_min`:`lat_max`/levels=(0,10000,10000) btdata[y=`lat_min`:`lat_max`,x=`lon_min`:`lon_max`]
endif

endif

if `station eq 1` then
go fer_psal_station_loc_overlay
endif

say Plot is finished
say To adjust parameters, use the command line to pass arguments
say For this file, the form to pass arguments is
say go fer_psal_map_dens time_start time_end dens_min dens_max lat_min lat_max lon_min lon_max iland station depth_axis con_lev